{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.05";
    nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixos-unstable";
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    disko = {
      url = "github:nix-community/disko";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nur.url = "github:nix-community/nur";
    emacs-overlay = {
    	url = "github:nix-community/emacs-overlay";
	inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = inputs @ { self, disko, nixpkgs, nixpkgs-unstable, home-manager, emacs-overlay, ... }:
    let
      system = "x86_64-linux";
      overlay-unstable = final: prev: {
        unstable = import nixpkgs-unstable {
          inherit system;
          config.allowUnfree = true; # Allow unfree packages globally
        };
      };

    in rec {
      mkSystem = {host, ...}: nixpkgs.lib.nixosSystem {
        inherit system;

          modules = [
            ./configuration.nix
	    ./options.nix
            ./pkgs
            host
            home-manager.nixosModules.home-manager
            disko.nixosModules.disko
            {
              home-manager.useGlobalPkgs = true; # Use global packages in home-manager
              home-manager.useUserPackages = true; # Use user packages in home-manager

              home-manager.extraSpecialArgs = {
                inherit inputs;
              };
            }
          ];

          specialArgs = {
            inherit inputs home-manager;
          };

          pkgs = import nixpkgs {
            inherit system;
            config.allowUnfree = true; # Allow unfree packages globally

            overlays = [
              inputs.nur.overlays.default
	      emacs-overlay.overlays.default
              overlay-unstable
            ];
          };

      };

      nixosConfigurations = {
        vm = mkSystem {
          host = ./hosts/vm.nix;
        };
        laptop = mkSystem {
          host = ./hosts/laptop;
        };
      };
    };
}